**Year to Date total**

The year-to-date aggregates data starting on January 1 of the year, as shown in Figure



The year-to-date total of a measure filters all the months that are in the year of the last date available in the filter context, and whose month is less than or equal to the month of that date:

Sales YTD :=

VAR LastMonthAvailable = MAX ( 'Date'[Year Month Number] )

VAR LastYearAvailable = MAX ( 'Date'[Year] )

VAR Result =

    CALCULATE (

        [Sales Amount],

        REMOVEFILTERS ( 'Date' ),

        'Date'[Year Month Number] <= LastMonthAvailable,

        'Date'[Year] = LastYearAvailable

    )

RETURN

    Result

If the report uses a hierarchy based on the fiscal year, then the measure must filter the corresponding columns with the word “Fiscal” before the acronym identifying the time intelligence calculation. For example, the Sales Fiscal YTD measure uses Fiscal Year Number instead of Year; however, it does not change the filter over Year Month Number because that column is identical for both fiscal and calendar hierarchies:

Sales Fiscal YTD :=

VAR LastMonthAvailable = MAX ( 'Date'[Year Month Number] )

VAR LastFiscalYearAvailable = MAX ( 'Date'[Fiscal Year Number] )

VAR Result =

    CALCULATE (

        [Sales Amount],

        REMOVEFILTERS ( 'Date' ),


        'Date'[Year Month Number] <= LastMonthAvailable,

        'Date'[Fiscal Year Number] = LastFiscalYearAvailable

    )

RETURN

    Result



The year-to-date total of a measure can rely on the [**DATESYTD**](https://dax.guide/datesytd/?aff=dax-patterns) function this way:

Sales YTD (simple) :=

CALCULATE (

    [Sales Amount],

    DATESYTD ( 'Date'[Date] )

)

[**DATESYTD**](https://dax.guide/datesytd/?aff=dax-patterns) returns the set of dates from the first day of the current year, up to the last date visible in the filter context. Therefore, the Sales YTD (simple) measure shows data even for future dates in the year. We can avoid this behavior in the Sales YTD measure by returning a result only when the ShowValueForDates measure returns TRUE:

Sales YTD :=

IF (

    [ShowValueForDates],

    CALCULATE (


        [Sales Amount],

        DATESYTD ( 'Date'[Date] )

    )

)

If the report is based on a fiscal year that does not correspond to the calendar year, [**DATESYTD**](https://dax.guide/datesytd/?aff=dax-patterns) requires an additional argument to identify the last day of the fiscal year. Take for example, the report in Figure 2.



The Sales Fiscal YTD measure specifies the last day and month of the fiscal year in the second argument of [**DATESYTD**](https://dax.guide/datesytd/?aff=dax-patterns). The following measure uses June 30 as the last day of the fiscal year. The second argument of [**DATESYTD**](https://dax.guide/datesytd/?aff=dax-patterns) must be a constant value (also called a literal) corresponding to the definition of the fiscal year in the Date table; it cannot be computed dynamically:

Sales Fiscal YTD :=

IF (

    [ShowValueForDates],

    CALCULATE (

        [Sales Amount],

        DATESYTD ( 'Date'[Date], "6-30" )

    )

)

Sales YTD (2) :=

IF (

    [ShowValueForDates],

    TOTALYTD (

        [Sales Amount],

        'Date'[Date]

    )

)

Sales Fiscal YTD (2) :=

IF (

    [ShowValueForDates],

    TOTALYTD (

        [Sales Amount],

        'Date'[Date],

        "6-30"

    )

)